Поиск PersistentArrayMap по части ключей

Question

Есть файл со строками вида "Word1 Word2 100", по ним создаются элементы:

(defn file-lines
  [file-name]
  (line-seq (io/reader file-name)))


(defn create-element [line]
  (let [[a b c] (str/split line #"\s+")]
    {:first a :second b :number c}))


(defn elements []
  (->>
    (file-lines "resources/file")
    (map #(create-element %))))

И строка "Word1 Word2". Как можно проверить, что такой элемент содержится в elements (т.е. игнорируя :number)? И если содержится вернуть найденный элемент, иначе этот элемент с :number 0? Думал проводить сравнение с select-keys, но тогда теряется :number.

Answer 1

Думал проводить сравнение с select-keys, но тогда теряется :number.

Это смотря где делать select-keys. Если делать это в предикате для filter для выкидывания неподходящих мапов, то вычисленные им мапы вы нигде больше не увидите, т. к. они персистентные и на исходные значения не влияют:

(let [src [{:first "a" :second "b" :number 42}
           {:first "c" :second "d" :number 7}
           {:first "e" :second "f" :number 10}]
      pred (fn [element] (-> element (select-keys [:first :second])
                                     (= {:first "c" :second "d"})))]
  (filter pred src)) ; => ({:first "c", :second "d", :number 7})

Таких элементов может потенциально быть много, поэтому возвращается список мапов.

---

А можно пойти вообще другим путём и сделать структуру данных другого вида, мап с ключами [слово1 слово2] и значениями число. С помощью get найти (или не найти) нужное значение проще простого:

(let [src {["a" "b"] 42
           ["c" "d"] 7
           ["e" "f"] 10}]
  (println (get src ["c" "d"] 0)) ; 7
  (println (get src ["y" "z"] 0))) ; 0

А ещё с помощью juxt можно сделать функцию, которая выдаст вектор значений по нужным вам ключам, дальше тоже несложно.

((juxt :a :c) {:a 1 :b 2 :c 3}) ; => [1 3]

Способов много. Пробовать все придётся долго :)

Answer 2

Можно создать ассоциативный массив где ключом будет [Word1 Word2] а значением то что в number, т.е.:

{[Word1 Word2] 0
 [Word3 Word4] 1}

Тогда, для его создания вы пишите:

(reduce
  (fn [acc line]
    (let [[a b c] (str/split line #"\s+")]
      (assoc acc [a b] c)))
    {}
    (io/reader file-name))

Для поиска используете функцию (get map key not-found)

(get lines-map [Word1 Word2] 0)

Answer 3

для этого есть keep:

(defn process [words maps]
  (keep #(if (= words ((juxt :first :second) %))
           %
           (assoc % :number 0))
        maps))

(process ["a" "b"]
         [{:first "x" :second "b" :number 1}
          {:first "a" :second "b" :number 101}
          {:first "a" :second "y" :number 21}
          {:first "a" :second "b" :number 42}])
;;=> ({:first "x", :second "b", :number 0} 
;;    {:first "a", :second "b", :number 101} 
;;    {:first "a", :second "y", :number 0} 
;;    {:first "a", :second "b", :number 42})